อื่น ๆ
ตำแหน่งปัจจุบัน: หน้าแรก>> ชิ้นส่วน>>อื่น ๆ>>
  • หมวดหมู่
  • ไดโอด
  • บริดจ์เรกติไฟเออร์
  • MOSFET
  • อื่น ๆ
  • 基于 51 单片机的红外线遥控器解码程序设计
    基于 51 单片机的红外线遥控器解码程序设计
  • 基于 51 单片机的红外线遥控器解码程序设计
  •   วันที่เผยแพร่: 2019-10-16  จำนวนเข้าชม: 2,595

    下面是一个对 51 实验板配套的红外线遥控器的解码程序, 它可以把红外遥控器每一个按键的键值读出来, 并且通过实验板上 P1 口的 8 个LED显示出来, 在解码成功的同时并且能发出“嘀嘀嘀”的提示音.

    基于 51 单片机的红外线遥控器解码程序设计

     

    ;=================================================

    ; 红外遥控接收

    ;=================================================

    ; ew51 仿真编程器 配套实验板学习例程

    ;

    ; 中山单片机学习网 智佳科技 逸风

    ;

    ; http://www.zsMCU.com

    ; E-mail:info@zsmcu.com

    ;=================================================

    ORG 0000H

    MAIN:

    JNB P2.2, IR ;遥控扫描

    LJMP MAIN ;在正常无遥控信号时, 一体化红外接收头输出是高电平, 程序一直在循环.

    ;=================================================

    ; 解码程序

    IR:

    ;以下对遥控信号的 9000 微秒的初始低电平信号的识别, 波形见图5.

    MOV R6, #10

    IR_SB:

    ACALL DELAY882 ;调用 882 微秒延时子程序

    JB P2.2, IR_ERROR ;延时 882 微秒后判断 P2.2 脚是否出现高电平如果有就ออกจากระบบ解码程序

    DJNZ R6, IR_SB ;重复 10 次, 目的是检测在 8820 微秒内如果出现高电平就ออกจากระบบ解码程序

    ;识别连发码, 和跳过 4.5ma 的高电平.

    JNB P2.2, $ ;等待高电平避开 9 毫秒低电平引导脉冲

    ACALL DELAY2400

    JNB P2.2, IR_Rp ;这里为低电平, 认为是连发码信号, 见图6.

    ACALL DELAY2400 ;延时 4.74 毫秒避开 4.5 毫秒 ผลลัพธ์码

    ;以下 32 数据码的读取 , 0和1的识别 请看图2

    MOV R1, #1AH ;设定 1AH 为起始RAM区

    MOV R2, #4

    IR_4BYTE:

    MOV R3, #8

    IR_8BIT:

    JNB P2.2, $ ;等待地址码第一位的高电平信号

    LCALL DELAY882 ;高电平开始后用 882 微秒的时间尺去判断信号此时的高低电平状态

    MOV C, P2.2 ;将 P2.2 引脚此时的电平状态 0 或 1 存入 C 中

    JNC IR_8BIT_0 ;如果为 0 就跳转到 IR_8BIT_0

    LCALL DELAY1000

    IR_8BIT_0:

    MOV A, @R1 ;将 R1 中地址的给 A

    RRC A ;将 C 中的值 0 或 1 移入 A 中的最低位

    MOV @R1, A ;将 A 中的数暂时存放在 R1 中

    DJNZ R3, IR_8BIT ;接收地址码的高 8 位

    INC R1 ;对 R1 中的值加 1, 换下一个 RAM

    DJNZ R2, IR_4BYTE ;接收完 16 位地址码和 8 位数据码和 8 位数据,

    ;存放在 1AH/1BH/1CH/1DH 的 RAM 中

    ;解码成功

    JMP IR_GOTO

    IR_Rp:

    ;这里为重复码执行处

    ;按住遥控按键时, 每过 108ms 就到这里来

    JMP IR_GOTO

    IR_ERROR:

    ;错语ออกจากระบบ

    LJMP MAIN ;ออกจากระบบ解码子程序

    ;=================================================

    ;遥控执行部份

    IR_GOTO:

    ;这里还要判断 1AH 和 1BH 两个系统码或用户码, 用于识别不同的遥控器

    ;MOV A, 1AH

    ;CJNE A, #xxH, IR_ERROR ;用户码1不对则ออกจากระบบ

    ;MOV A, 1BH

    ;CJNE A, #xxH, IR_ERROR ;用户码2不对则ออกจากระบบ

    ;判断两个数据码是否相反

    MOV A, 1CH

    CPL A

    CJNE A, 1DH, IR_ERROR ;两个数据码不相反则ออกจากระบบ

    ;遥控执行部份

    ;MOV A, 1DH ;判断对应按键

    ;CJNE A, #xxH, {1}6

    ;LJMP -à跳到对应按键执行处

    ;CJNE A, #xxH, {1}6

    ;LJMP -à跳到对应按键执行处

    ;.

    MOV P1, 1DH ;将按键的键值通过 P1 口的 8 个 LED 显示出来!

    CLR P2.3 ;蜂鸣器鸣响-嘀嘀嘀-的声音, 表示解码成功

    LCALL DELAY2400

    LCALL DELAY2400

    LCALL DELAY2400

    SETB P2.3 ;蜂鸣器停止

    ;ล้าง遥控值使连按失效

    MOV 1AH, #00H

    MOV 1BH, #00H

    MOV 1CH, #00H

    MOV 1DH, #00H

    LJMP MAIN

    ;=================================================

    ; 延时子程序

    ;=============================882

    DELAY882: ;1.085x ( (202x4) +5) =882

    MOV R7, #202

    DELAY882_A:

    NOP

    NOP

    DJNZ R7, DELAY882_A

    RET

    ;=============================1000

    DELAY1000: ;1.085x ( (229x4) +5) =999.285

    MOV R7, #229

    DELAY1000_A:

    NOP

    NOP

    DJNZ R7, DELAY1000_A

    RET

    ;=============================2400

    DELAY2400: ;1.085x ( (245x9) +5) =2397.85

    MOV R7, #245

    DELAY2400_A:

    NOP

    NOP

    NOP

    NOP

    NOP

    NOP

    NOP

    DJNZ R7, DELAY2400_A

    RET

    END
    来源; 21ic


  • ·บทความก่อนหน้า:
    ·บทความถัดไป:
  • ข่าวที่เกี่ยวข้อง
    บริษัท เซินเจิ้น รื่อเยว่เฉิน เทคโนโลยี จำกัด
    ที่อยู่: ชั้น 3 อาคาร 27 โซน A เมืองอุตสาหกรรมถานโถว 2 ซงกัง เป่าอัน เซินเจิ้น
    โทร: 0755-2955 6626
    แฟกซ์: 0755-2978 1585
    มือถือ: 131 1300 0010
    อีเมล: hu@szryc.com

    บริษัท เซินเจิ้น รื่อเยว่เฉิน เทคโนโลยี จำกัด สงวนลิขสิทธิ์ Copyright©2010-2027 www.szryc.com โทร: 13113000010 ใบอนุญาต ICP เลขที่ 2021111333 (กวางตุ้ง)